最近需要使用SourceInsight查看分析在Linux系統(tǒng)下開發(fā)的項目代碼，我們知道Linux系統(tǒng)中文本文件默認編碼格式是UTF-8，而Windows中文系統(tǒng)中的默認編碼格式是Gb2312。系統(tǒng)內(nèi)的編碼格式有所區(qū)別倒無傷大雅，關鍵的是SourceInsight竟不支持UTF-8，導致項目代碼內(nèi)的中文注釋全部亂碼！
既然SourceInsight不支持UTF-8編碼的文件，那我們就得想辦法將UTF-8的代碼文件轉化為GB2312編碼的。首先想到的是到網(wǎng)上搜一下“批量編碼轉換工具”，結果下載后發(fā)現(xiàn)編碼轉換后的文件總是出現(xiàn)亂碼，可能是工具的bug吧。既然不能使用工具轉換，那就自己寫一個程序進行編碼轉換，但是細想一下覺得C++/java的編碼轉換程序?qū)懫饋碛直容^啰嗦，要是在Linux下寫一個shell腳本就能輕松搞定了。還好Windows下有vbs腳本可以幫助我們輕松達到這個目的。
'函數(shù)名稱:ReadFile
'作用:利用AdoDb.Stream對象來讀取各種格式的文本文件
'-------------------------------------------------
Function ReadFile(FileUrl, CharSet)
Dim Str
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.loadfromfile FileUrl
Str = stm.readtext
stm.Close
Set stm = Nothing
ReadFile = Str
End Function
我們使用ReadFile函數(shù)讀取文件，其中FileUrl指定文件的路徑，CharSet指定文件的原始編碼格式，使用adodb.stream對象讀取文件內(nèi)容到Str。
'函數(shù)名稱:WriteToFile
'作用:利用AdoDb.Stream對象來寫入各種格式的文本文件
'-------------------------------------------------
Function WriteToFile (FileUrl, Str, CharSet)
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile FileUrl, 2
stm.flush
stm.Close
Set stm = Nothing
End Function
然后使用WriteToFile將Str寫回原文件FileUrl，并設定新的編碼CharSet。
'函數(shù)名稱:ConvertFile
'作用:將一個文件進行編碼轉換
'-------------------------------------------------
Function ConvertFile(FileUrl)
Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function
這樣ConvertFile對上述兩個函數(shù)封裝，實現(xiàn)文件FileUrl的編碼轉換，其中原始編碼SrcCode與目的編碼DestCode為全局變量。
如果僅對一個文件進行編碼轉換，我們不必這么大費周章。我們希望能對任意的文件或文件夾內(nèi)的所有文件進行編碼轉換，達到批量轉換的目的。
'函數(shù)名稱:ConvertDir
'作用:將任意目錄內(nèi)的文件進行編碼轉換
'-------------------------------------------------
Function ConvertDir(DirUrl)
If fs.FileExists(DirUrl) Then
Call ConvertFile(DirUrl)
Else
Call SearchDir(DirUrl)
End If
End Function
函數(shù)ConvertDir對任意路徑的文件/文件夾進行編碼轉換，使用scripting.filesystemobject對象的FileExists函數(shù)判斷路徑對應的是文件還是文件夾，如果是文件則直接調(diào)用ConvertFile進行編碼轉換，否則調(diào)用SearchDir處理文件夾。
'函數(shù)名稱:SearchDir
'作用:遞歸查找目錄內(nèi)的文件，進行編碼轉換
'-------------------------------------------------
Function SearchDir(path)
Set folder = fs.getfolder(path)
Set subfolders = folder.subfolders
Set Files = folder.Files
For Each i In Files
Call ConvertFile(i.path)
Next
For Each j In subfolders
Call SearchDir(j.path)
Next
End Function
函數(shù)SearchDir是遞歸的，首先調(diào)用getfolder創(chuàng)建文件夾對象，然后取出文件夾內(nèi)的子文件夾集合subfolders和子文件集合files。對于每個子文件，直接調(diào)用ConvertFile進行編碼轉換即可，而對于每個子文件夾，則遞歸調(diào)用SearchDir重復處理。
'設置編碼：默認 utf-8 --> gb2312
'-------------------------------------------------
SrcCode="utf-8"
DestCode="gb2312"
'-------------------------------------------------
'解析參數(shù)
'-------------------------------------------------
Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
For I = 0 To objArgs.Count - 1
FileUrl = objArgs(I)
Call ConvertDir(FileUrl)
Next
Else
MsgBox "沒有文件/文件夾被拖入！"
wscript.quit
End If
MsgBox "轉換成功！"
最后通過解析腳本文件的參數(shù)，由于每個參數(shù)對應一個文件/文件夾的路徑，將之傳遞給ConvertDir即可。這里默認的是將UTF-8編碼轉化為GB2312編碼，讀者可以根據(jù)自身需要自行修改。
將上述代碼保存為ConvertCode.vbs，只需要將任意多個文件選中拖動到該腳本文件上即可?；蛘呤褂妹钚?。
需要注意的是文件編碼是就地轉換的，在轉換之前最好將原文件/文件夾進行備份。
最后附上腳本文件的所有代碼。
'-------------------------------------------------
'設置編碼：默認 utf-8 --> gb2312
'-------------------------------------------------
SrcCode="utf-8"
DestCode="gb2312"
'-------------------------------------------------
'解析參數(shù)
'-------------------------------------------------
Set fs = CreateObject("scripting.filesystemobject")
Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
For I = 0 To objArgs.Count - 1
FileUrl = objArgs(I)
Call ConvertDir(FileUrl)
Next
Else
MsgBox "沒有文件/文件夾被拖入！"
wscript.quit
End If
MsgBox "轉換成功！"
'-------------------------------------------------
'函數(shù)名稱:ConvertDir
'作用:將任意目錄內(nèi)的文件進行編碼轉換
'-------------------------------------------------
Function ConvertDir(DirUrl)
If fs.FileExists(DirUrl) Then
Call ConvertFile(DirUrl)
Else
Call SearchDir(DirUrl)
End If
End Function
'-------------------------------------------------
'函數(shù)名稱:SearchDir
'作用:遞歸查找目錄內(nèi)的文件，進行編碼轉換
'-------------------------------------------------
Function SearchDir(path)
Set folder = fs.getfolder(path)
Set subfolders = folder.subfolders
Set Files = folder.Files
For Each i In Files
Call ConvertFile(i.path)
Next
For Each j In subfolders
Call SearchDir(j.path)
Next
End Function
'-------------------------------------------------
'函數(shù)名稱:ConvertFile
'作用:將一個文件進行編碼轉換
'-------------------------------------------------
Function ConvertFile(FileUrl)
Call WriteToFile(FileUrl, ReadFile(FileUrl, SrcCode), DestCode)
End Function
'-------------------------------------------------
'函數(shù)名稱:ReadFile
'作用:利用AdoDb.Stream對象來讀取各種格式的文本文件
'-------------------------------------------------
Function ReadFile(FileUrl, CharSet)
Dim Str
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.loadfromfile FileUrl
Str = stm.readtext
stm.Close
Set stm = Nothing
ReadFile = Str
End Function
'-------------------------------------------------
'函數(shù)名稱:WriteToFile
'作用:利用AdoDb.Stream對象來寫入各種格式的文本文件
'-------------------------------------------------
Function WriteToFile (FileUrl, Str, CharSet)
Set stm = CreateObject("Adodb.Stream")
stm.Type = 2
stm.mode = 3
stm.charset = CharSet
stm.Open
stm.WriteText Str
stm.SaveToFile FileUrl, 2
stm.flush
stm.Close
Set stm = Nothing
End FunctionView Code
